| 1 | /* Startup code for programs linked with GNU libc. |
| 2 | Copyright (C) 1998-2026 Free Software Foundation, Inc. |
| 3 | This file is part of the GNU C Library. |
| 4 | |
| 5 | The GNU C Library is free software; you can redistribute it and/or |
| 6 | modify it under the terms of the GNU Lesser General Public |
| 7 | License as published by the Free Software Foundation; either |
| 8 | version 2.1 of the License, or (at your option) any later version. |
| 9 | |
| 10 | In addition to the permissions in the GNU Lesser General Public |
| 11 | License, the Free Software Foundation gives you unlimited |
| 12 | permission to link the compiled version of this file with other |
| 13 | programs, and to distribute those programs without any restriction |
| 14 | coming from the use of this file. (The GNU Lesser General Public |
| 15 | License restrictions do apply in other respects; for example, they |
| 16 | cover modification of the file, and distribution when not linked |
| 17 | into another program.) |
| 18 | |
| 19 | Note that people who make modified versions of this file are not |
| 20 | obligated to grant this special exception for their modified |
| 21 | versions; it is their choice whether to do so. The GNU Lesser |
| 22 | General Public License gives permission to release a modified |
| 23 | version without this exception; this exception also makes it |
| 24 | possible to release a modified version which carries forward this |
| 25 | exception. |
| 26 | |
| 27 | The GNU C Library is distributed in the hope that it will be useful, |
| 28 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 29 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| 30 | Lesser General Public License for more details. |
| 31 | |
| 32 | You should have received a copy of the GNU Lesser General Public |
| 33 | License along with the GNU C Library; if not, see |
| 34 | <https://www.gnu.org/licenses/>. */ |
| 35 | |
| 36 | #include <sysdep.h> |
| 37 | |
| 38 | /* We do not want .eh_frame info for crt1.o since crt1.o is linked |
| 39 | before crtbegin.o, the file defining __EH_FRAME_BEGIN__. */ |
| 40 | #undef cfi_startproc |
| 41 | #define cfi_startproc |
| 42 | #undef cfi_endproc |
| 43 | #define cfi_endproc |
| 44 | |
| 45 | /* These are the various addresses we require. */ |
| 46 | #ifdef PIC |
| 47 | .section ".data" |
| 48 | #else |
| 49 | .section ".rodata" |
| 50 | #endif |
| 51 | .align 2 |
| 52 | L(start_addresses): |
| 53 | .long _SDA_BASE_ |
| 54 | .long main |
| 55 | .long 0 /* Used to be init. */ |
| 56 | .long 0 /* Used to be fini. */ |
| 57 | ASM_SIZE_DIRECTIVE(L(start_addresses)) |
| 58 | |
| 59 | .section ".text" |
| 60 | ENTRY(_start) |
| 61 | /* Save the stack pointer, in case we're statically linked under Linux. */ |
| 62 | mr r9,r1 |
| 63 | /* Set up an initial stack frame, and clear the LR. */ |
| 64 | clrrwi r1,r1,4 |
| 65 | #ifdef PIC |
| 66 | SETUP_GOT_ACCESS(r13,got_label) |
| 67 | li r0,0 |
| 68 | #else |
| 69 | li r0,0 |
| 70 | #endif |
| 71 | stwu r1,-16(r1) |
| 72 | mtlr r0 |
| 73 | stw r0,0(r1) |
| 74 | /* Set r13 to point at the 'small data area', and put the address of |
| 75 | start_addresses in r8. Also load the GOT pointer so that new PLT |
| 76 | calls work, like the one to __libc_start_main. */ |
| 77 | #ifdef PIC |
| 78 | addis r30,r13,_GLOBAL_OFFSET_TABLE_-got_label@ha |
| 79 | addis r8,r13,L(start_addresses)-got_label@ha |
| 80 | addi r30,r30,_GLOBAL_OFFSET_TABLE_-got_label@l |
| 81 | lwzu r13, L(start_addresses)-got_label@l(r8) |
| 82 | #else |
| 83 | lis r8,L(start_addresses)@ha |
| 84 | lwzu r13,L(start_addresses)@l(r8) |
| 85 | #endif |
| 86 | /* and continue in libc-start, in glibc. */ |
| 87 | b JUMPTARGET(__libc_start_main) |
| 88 | END(_start) |
| 89 | |
| 90 | /* Define a symbol for the first piece of initialized data. */ |
| 91 | .section ".data" |
| 92 | .globl __data_start |
| 93 | __data_start: |
| 94 | .long 0 |
| 95 | weak_alias (__data_start, data_start) |