| 1 | .text |
| 2 | .global __clone |
| 3 | .hidden __clone |
| 4 | .type __clone, %function |
| 5 | __clone: |
| 6 | # int clone(fn, stack, flags, arg, ptid, tls, ctid) |
| 7 | # a b c d e f g |
| 8 | # 3 4 5 6 7 8 9 |
| 9 | # pseudo C code: |
| 10 | # tid = syscall(SYS_clone,c,b,e,f,g); |
| 11 | # if (!tid) syscall(SYS_exit, a(d)); |
| 12 | # return tid; |
| 13 | |
| 14 | # SYS_clone = 120 |
| 15 | # SYS_exit = 1 |
| 16 | |
| 17 | # store non-volatile regs r30, r31 on stack in order to put our |
| 18 | # start func and its arg there |
| 19 | stwu 1, -16(1) |
| 20 | stw 30, 8(1) |
| 21 | stw 31, 12(1) |
| 22 | |
| 23 | # save r3 (func) into r30, and r6(arg) into r31 |
| 24 | mr 30, 3 |
| 25 | mr 31, 6 |
| 26 | |
| 27 | # create initial stack frame for new thread |
| 28 | clrrwi 4, 4, 4 |
| 29 | li 0, 0 |
| 30 | stwu 0, -16(4) |
| 31 | |
| 32 | #move c into first arg |
| 33 | mr 3, 5 |
| 34 | #mr 4, 4 |
| 35 | mr 5, 7 |
| 36 | mr 6, 8 |
| 37 | mr 7, 9 |
| 38 | |
| 39 | # move syscall number into r0 |
| 40 | li 0, 120 |
| 41 | |
| 42 | sc |
| 43 | |
| 44 | # check for syscall error |
| 45 | bns+ 1f # jump to label 1 if no summary overflow. |
| 46 | #else |
| 47 | neg 3, 3 #negate the result (errno) |
| 48 | 1: |
| 49 | # compare sc result with 0 |
| 50 | cmpwi cr7, 3, 0 |
| 51 | |
| 52 | # if not 0, restore stack and return |
| 53 | beq cr7, 2f |
| 54 | |
| 55 | lwz 30, 8(1) |
| 56 | lwz 31, 12(1) |
| 57 | addi 1, 1, 16 |
| 58 | |
| 59 | blr |
| 60 | |
| 61 | 2: |
| 62 | #else: we're the child |
| 63 | #call funcptr: move arg (d) into r3 |
| 64 | mr 3, 31 |
| 65 | #move r30 (funcptr) into CTR reg |
| 66 | mtctr 30 |
| 67 | # call CTR reg |
| 68 | bctrl |
| 69 | # mov SYS_exit into r0 (the exit param is already in r3) |
| 70 | li 0, 1 |
| 71 | sc |