1const std = @import("std");
2const crypto = std.crypto;
3const mem = std.mem;
4const fmt = std.fmt;
5
6const Sha512 = crypto.hash.sha2.Sha512;
7
8const EncodingError = crypto.errors.EncodingError;
9const IdentityElementError = crypto.errors.IdentityElementError;
10const WeakPublicKeyError = crypto.errors.WeakPublicKeyError;
11
12/// X25519 DH function.
13pub const X25519 = struct {
14 /// The underlying elliptic curve.
15 pub const Curve = @import("curve25519.zig").Curve25519;
16 /// Length (in bytes) of a secret key.
17 pub const secret_length = 32;
18 /// Length (in bytes) of a public key.
19 pub const public_length = 32;
20 /// Length (in bytes) of the output of the DH function.
21 pub const shared_length = 32;
22 /// Seed (for key pair creation) length in bytes.
23 pub const seed_length = 32;
24
25 /// An X25519 key pair.
26 pub const KeyPair = struct {
27 /// Public part.
28 public_key: [public_length]u8,
29 /// Secret part.
30 secret_key: [secret_length]u8,
31
32 /// Deterministically derive a key pair from a cryptograpically secure secret seed.
33 ///
34 /// Except in tests, applications should generally call `generate()` instead of this function.
35 pub fn generateDeterministic(seed: [seed_length]u8) IdentityElementError!KeyPair {
36 const kp = KeyPair{
37 .public_key = try X25519.recoverPublicKey(seed),
38 .secret_key = seed,
39 };
40 return kp;
41 }
42
43 /// Generate a new, random key pair.
44 pub fn generate(io: std.Io) KeyPair {
45 var random_seed: [seed_length]u8 = undefined;
46 while (true) {
47 io.random(&random_seed);
48 return generateDeterministic(random_seed) catch {
49 @branchHint(.unlikely);
50 continue;
51 };
52 }
53 }
54
55 /// Create a key pair from an Ed25519 key pair
56 pub fn fromEd25519(ed25519_key_pair: crypto.sign.Ed25519.KeyPair) (IdentityElementError || EncodingError)!KeyPair {
57 const seed = ed25519_key_pair.secret_key.seed();
58 var az: [Sha512.digest_length]u8 = undefined;
59 Sha512.hash(&seed, &az, .{});
60 var sk = az[0..32].*;
61 Curve.scalar.clamp(&sk);
62 const pk = try publicKeyFromEd25519(ed25519_key_pair.public_key);
63 return KeyPair{
64 .public_key = pk,
65 .secret_key = sk,
66 };
67 }
68 };
69
70 /// Compute the public key for a given private key.
71 pub fn recoverPublicKey(secret_key: [secret_length]u8) IdentityElementError![public_length]u8 {
72 const q = try Curve.basePoint.clampedMul(secret_key);
73 return q.toBytes();
74 }
75
76 /// Compute the X25519 equivalent to an Ed25519 public eky.
77 pub fn publicKeyFromEd25519(ed25519_public_key: crypto.sign.Ed25519.PublicKey) (IdentityElementError || EncodingError)![public_length]u8 {
78 const pk_ed = try crypto.ecc.Edwards25519.fromBytes(ed25519_public_key.bytes);
79 const pk = try Curve.fromEdwards25519(pk_ed);
80 return pk.toBytes();
81 }
82
83 /// Compute the scalar product of a public key and a secret scalar.
84 /// Note that the output should not be used as a shared secret without
85 /// hashing it first.
86 pub fn scalarmult(secret_key: [secret_length]u8, public_key: [public_length]u8) IdentityElementError![shared_length]u8 {
87 const q = try Curve.fromBytes(public_key).clampedMul(secret_key);
88 return q.toBytes();
89 }
90};
91
92const htest = @import("../test.zig");
93
94test "public key calculation from secret key" {
95 var sk: [32]u8 = undefined;
96 var pk_expected: [32]u8 = undefined;
97 _ = try fmt.hexToBytes(sk[0..], "8052030376d47112be7f73ed7a019293dd12ad910b654455798b4667d73de166");
98 _ = try fmt.hexToBytes(pk_expected[0..], "f1814f0e8ff1043d8a44d25babff3cedcae6c22c3edaa48f857ae70de2baae50");
99 const pk_calculated = try X25519.recoverPublicKey(sk);
100 try std.testing.expectEqual(pk_calculated, pk_expected);
101}
102
103test "rfc7748 vector1" {
104 const secret_key = [32]u8{ 0xa5, 0x46, 0xe3, 0x6b, 0xf0, 0x52, 0x7c, 0x9d, 0x3b, 0x16, 0x15, 0x4b, 0x82, 0x46, 0x5e, 0xdd, 0x62, 0x14, 0x4c, 0x0a, 0xc1, 0xfc, 0x5a, 0x18, 0x50, 0x6a, 0x22, 0x44, 0xba, 0x44, 0x9a, 0xc4 };
105 const public_key = [32]u8{ 0xe6, 0xdb, 0x68, 0x67, 0x58, 0x30, 0x30, 0xdb, 0x35, 0x94, 0xc1, 0xa4, 0x24, 0xb1, 0x5f, 0x7c, 0x72, 0x66, 0x24, 0xec, 0x26, 0xb3, 0x35, 0x3b, 0x10, 0xa9, 0x03, 0xa6, 0xd0, 0xab, 0x1c, 0x4c };
106
107 const expected_output = [32]u8{ 0xc3, 0xda, 0x55, 0x37, 0x9d, 0xe9, 0xc6, 0x90, 0x8e, 0x94, 0xea, 0x4d, 0xf2, 0x8d, 0x08, 0x4f, 0x32, 0xec, 0xcf, 0x03, 0x49, 0x1c, 0x71, 0xf7, 0x54, 0xb4, 0x07, 0x55, 0x77, 0xa2, 0x85, 0x52 };
108
109 const output = try X25519.scalarmult(secret_key, public_key);
110 try std.testing.expectEqual(output, expected_output);
111}
112
113test "rfc7748 vector2" {
114 const secret_key = [32]u8{ 0x4b, 0x66, 0xe9, 0xd4, 0xd1, 0xb4, 0x67, 0x3c, 0x5a, 0xd2, 0x26, 0x91, 0x95, 0x7d, 0x6a, 0xf5, 0xc1, 0x1b, 0x64, 0x21, 0xe0, 0xea, 0x01, 0xd4, 0x2c, 0xa4, 0x16, 0x9e, 0x79, 0x18, 0xba, 0x0d };
115 const public_key = [32]u8{ 0xe5, 0x21, 0x0f, 0x12, 0x78, 0x68, 0x11, 0xd3, 0xf4, 0xb7, 0x95, 0x9d, 0x05, 0x38, 0xae, 0x2c, 0x31, 0xdb, 0xe7, 0x10, 0x6f, 0xc0, 0x3c, 0x3e, 0xfc, 0x4c, 0xd5, 0x49, 0xc7, 0x15, 0xa4, 0x93 };
116
117 const expected_output = [32]u8{ 0x95, 0xcb, 0xde, 0x94, 0x76, 0xe8, 0x90, 0x7d, 0x7a, 0xad, 0xe4, 0x5c, 0xb4, 0xb8, 0x73, 0xf8, 0x8b, 0x59, 0x5a, 0x68, 0x79, 0x9f, 0xa1, 0x52, 0xe6, 0xf8, 0xf7, 0x64, 0x7a, 0xac, 0x79, 0x57 };
118
119 const output = try X25519.scalarmult(secret_key, public_key);
120 try std.testing.expectEqual(output, expected_output);
121}
122
123test "rfc7748 one iteration" {
124 const initial_value = [32]u8{ 0x09, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };
125 const expected_output = [32]u8{ 0x42, 0x2c, 0x8e, 0x7a, 0x62, 0x27, 0xd7, 0xbc, 0xa1, 0x35, 0x0b, 0x3e, 0x2b, 0xb7, 0x27, 0x9f, 0x78, 0x97, 0xb8, 0x7b, 0xb6, 0x85, 0x4b, 0x78, 0x3c, 0x60, 0xe8, 0x03, 0x11, 0xae, 0x30, 0x79 };
126
127 var k: [32]u8 = initial_value;
128 var u: [32]u8 = initial_value;
129
130 var i: usize = 0;
131 while (i < 1) : (i += 1) {
132 const output = try X25519.scalarmult(k, u);
133 u = k;
134 k = output;
135 }
136
137 try std.testing.expectEqual(k, expected_output);
138}
139
140test "rfc7748 1,000 iterations" {
141 // These iteration tests are slow so we always skip them. Results have been verified.
142 if (true) {
143 return error.SkipZigTest;
144 }
145
146 const initial_value = [32]u8{ 0x09, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };
147 const expected_output = [32]u8{ 0x68, 0x4c, 0xf5, 0x9b, 0xa8, 0x33, 0x09, 0x55, 0x28, 0x00, 0xef, 0x56, 0x6f, 0x2f, 0x4d, 0x3c, 0x1c, 0x38, 0x87, 0xc4, 0x93, 0x60, 0xe3, 0x87, 0x5f, 0x2e, 0xb9, 0x4d, 0x99, 0x53, 0x2c, 0x51 };
148
149 var k: [32]u8 = initial_value.*;
150 var u: [32]u8 = initial_value.*;
151
152 var i: usize = 0;
153 while (i < 1000) : (i += 1) {
154 const output = try X25519.scalarmult(&k, &u);
155 u = k;
156 k = output;
157 }
158
159 try std.testing.expectEqual(k, expected_output);
160}
161
162test "rfc7748 1,000,000 iterations" {
163 if (true) {
164 return error.SkipZigTest;
165 }
166
167 const initial_value = [32]u8{ 0x09, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };
168 const expected_output = [32]u8{ 0x7c, 0x39, 0x11, 0xe0, 0xab, 0x25, 0x86, 0xfd, 0x86, 0x44, 0x97, 0x29, 0x7e, 0x57, 0x5e, 0x6f, 0x3b, 0xc6, 0x01, 0xc0, 0x88, 0x3c, 0x30, 0xdf, 0x5f, 0x4d, 0xd2, 0xd2, 0x4f, 0x66, 0x54, 0x24 };
169
170 var k: [32]u8 = initial_value.*;
171 var u: [32]u8 = initial_value.*;
172
173 var i: usize = 0;
174 while (i < 1000000) : (i += 1) {
175 const output = try X25519.scalarmult(&k, &u);
176 u = k;
177 k = output;
178 }
179
180 try std.testing.expectEqual(k[0..], expected_output);
181}
182
183test "edwards25519 -> curve25519 map" {
184 const ed_kp = try crypto.sign.Ed25519.KeyPair.generateDeterministic(@splat(0x42));
185 const mont_kp = try X25519.KeyPair.fromEd25519(ed_kp);
186 try htest.assertEqual("90e7595fc89e52fdfddce9c6a43d74dbf6047025ee0462d2d172e8b6a2841d6e", &mont_kp.secret_key);
187 try htest.assertEqual("cc4f2cdb695dd766f34118eb67b98652fed1d8bc49c330b119bbfa8a64989378", &mont_kp.public_key);
188}